c 바인딩을 만들고 있어요.

Cada.File 패키지를 만들고

Cada.File.Object 객체를 만들었어요.

파일 작업할 때 편하게 하기 좋죠.

sys_stat_h 같은 파일들은 gcc가 자동으로 dump 한 파일이에요.

-fdump-ada-spec 옵주면 .ads 파일 자동 생성합니다.

그 파일들만으로도 저수준 c 바인딩이 가능해요.

Cada에서는 그걸 감싸서 dlopen, dlsym 등 및 file 작업 등을 OOP로 제공하죠

ㅋㅋ

역시 Ada 좋네요 ㅎㅎ

package body Cada.File is
  use type Interfaces.C.Int;
  use type Interfaces.C.long;

  function c_open2 (path  : Interfaces.C.Char_Array;
                    flags : Interfaces.C.Int) return File_Descriptor;
  function c_open3 (path  : Interfaces.C.Char_Array;
                    flags : Interfaces.C.Int;
                    mode  : sys_types_h.mode_t) return File_Descriptor;
  pragma import (c, c_open2, "open");
  pragma import (c, c_open3, "open");

  function open (path  : String;
                 flags : File_Flags) return Object is
    new_fd : constant File_Descriptor :=
      c_open2 (Interfaces.C.to_c (path), Interfaces.C.Int (flags));
  begin
    if new_fd = -1 then
      declare
        error_code : constant Interfaces.C.int := Cada.Error.get_errno;
        error_msg  : constant String           :=
          "open(2) failed for path """ & path & """ (errno: " & error_code'image & ")";
      begin
        case error_code is
          when errno_h.EACCES =>
            raise Cada.Error.Permission_Denied with error_msg;
          when errno_h.ENOENT =>
            raise Cada.Error.No_Such_File_Or_Directory with error_msg;
          when errno_h.EEXIST =>
            raise Cada.Error.File_Exists with error_msg;
          when errno_h.EISDIR =>
            raise Cada.Error.Is_A_Directory with error_msg;
          when errno_h.ENOTDIR =>
            raise Cada.Error.Not_A_Directory with error_msg;
          when others =>
            declare
              errno_text : constant String := Cada.Error.get_error_message(error_code);
            begin
              raise Cada.Error.Unknown_Error with errno_text & ": " & error_msg;
            end;
        end case;
      end;
    end if;
    return (Ada.Finalization.Controlled with fd => new_fd);
  end open;

  -- open implementation (3 arguments)
  function open (path  : String;
                 flags : File_Flags;
                 mode  : Cada.Types.File_Mode) return Object is
    new_fd : constant File_Descriptor := c_open3 (Interfaces.C.to_c (path),
                                                  Interfaces.C.Int (flags),
                                                  sys_types_h.mode_t (mode));
  begin
    if new_fd = -1 then
      declare
        error_code : constant Interfaces.C.int := Cada.Error.get_errno;
        error_msg  : constant String           :=
          "open(2) failed for path """ & path & """ (errno: " & error_code'image & ")";
      begin
        case error_code is
          when errno_h.EACCES =>
            raise Cada.Error.Permission_Denied with error_msg;
          when errno_h.ENOENT =>
            raise Cada.Error.No_Such_File_Or_Directory with error_msg;
          when errno_h.EEXIST =>
            raise Cada.Error.File_Exists with error_msg;
          when errno_h.EISDIR =>
            raise Cada.Error.Is_A_Directory with error_msg;
          when errno_h.ENOTDIR =>
            raise Cada.Error.Not_A_Directory with error_msg;
          when others =>
            declare
              errno_text : constant String := Cada.Error.get_error_message(error_code);
            begin
              raise Cada.Error.Unknown_Error with errno_text & ": " & error_msg;
            end;
        end case;
      end;
    end if;
    return (Ada.Finalization.Controlled with fd => new_fd);
  end open;