(void) gfxFill (u8 x, u8 y, u16 fc, u16 bc, u32 addr);

        .ARM
        .ALIGN
        .GLOBL  gfxFill
@ r0 = x
@ r1 = y
@ r2 = fill color
@ r3 = boundary color
@ r4 = pixel addr
@ r5 = stack count
@ r6 = tmp test pixel

gfxFill:
        sub     sp,sp,#4         @ protect the stack so addr doesn't
                                 @  doesn't get overwritten.
        stmfd   r13!,{r0-r7,r14}

        ldr     r6,[r13,#40]     @ Get the screen base address

@ Calculate start address
        mov     r4,#480
        mul     r5,r4,r1
        add     r5,r5,r0,lsl #1
        add     r4,r5,r6         @ r4 = start address

        mov     r5,#0            @ set points on stack count to 0

1:      bl      9f               @ Is point filled?
        bcs     4f               @ yes

2:      sub     r1,r1,#1
        sub     r4,r4,#480
        bl      9f               @ Is point above this one set?
        bcc     2b               @ No, so check again
        add     r1,r1,#1
        add     r4,r4,#480

3:      sub     r0,r0,#1
        sub     r4,r4,#2
        bl      9f               @ Is point on the left set ?
        bcc     2b               @ No, so check above again
        add     r0,r0,#1
        add     r4,r4,#2

@ Plot a pixel at r0,r1 of color r2

        strh    r2,[r4]

        add     r1,r1,#1
        add     r4,r4,#480
        bl      9f               @ Is point below set ?
        bcc     5f               @ No

        sub     r1,r1,#1
        add     r0,r0,#1
        sub     r4,r4,#480
        add     r4,r4,#2
        bl      9f               @ Is point on the right set ?
        bcc     2b               @ No
        sub     r0,r0,#1
        sub     r4,r4,#2

@ Are there any more points on stack?

4:      cmp     r5,#0
        beq     8f               @ No

@ Get point on stack

        ldmfd   r13!,{r4,r7}     @ r4 = scrn adr, r7 = packed x/y
        mov     r1,r7,lsr #16    @ r1 = point y
        mov     r0,r7,lsl #16
        mov     r0,r0,lsr #16    @ r0 = point x

        sub     r5,r5,#1
        b       1b

5:
        sub     r1,r1,#1
        add     r0,r0,#1
        sub     r4,r4,#480
        add     r4,r4,#2
        bl      9f               @ Is point on the right set ?
        bcs     6f               @ Yes

        add     r1,r1,#1
        add     r4,r4,#480
        bl      9f               @ Is lower right point set ?
        bcc     7f               @ No

        sub     r1,r1,#1
        sub     r4,r4,#480

@ Save point position on stack

        add     r5,r5,#1         @ Increment points on stack count

@@@@ ADD STACK OVERFLOW TEST HERE @@@@@

        add     r7,r0,r1,lsl #16  @ pack x & y into r7

        stmfd   r13!,{r4,r7}  @ Save point on stack

@ Point below is not set

6:      add     r1,r1,#1
        sub     r0,r0,#1
        add     r4,r4,#480
        sub     r4,r4,#2
        b       3b

7:      sub     r0,r0,#1
        sub     r4,r4,#2
        b       3b

@ Exit fill routine

8:
        ldmfd   r13!,{r0-r7,r14}
        add     sp,sp,#4
        bx      r14

@ Clear Carry if pixel r0,r1 needs to be filled

9:
        cmps    r0,#240         @ is x coord out of bounds?
        bxcs    lr              @ yes, exit with carry set
        cmps    r1,#160         @ is y coord out of founds?
        bxcs    lr              @ yes exit with carry set

        ldrh    r6,[r4]

        cmps    r6,r2           @ Have we hit a filled spot?
        bxeq    lr              @ yes, exit with carry set

        cmps    r6,r3           @ Have we hit the boundary?
        bxeq    lr              @ yes, exit with carry set

@ Clear carry flag
        movs    r6,r0,lsl #1
        bx      lr